ꦫꦣꦺꦤ꧀ꦄꦤ꧀ꦠꦱꦺꦤ

PATH: usr / share / perl5 / vendor_perl

package YAML;
our $VERSION = '1.30';

use YAML::Mo;

use Exporter;
push @YAML::ISA, 'Exporter';
our @EXPORT = qw{ Dump Load };
our @EXPORT_OK = qw{ freeze thaw DumpFile LoadFile Bless Blessed };
our (
    $UseCode, $DumpCode, $LoadCode,
    $SpecVersion,
    $UseHeader, $UseVersion, $UseBlock, $UseFold, $UseAliases,
    $Indent, $SortKeys, $Preserve,
    $AnchorPrefix, $CompressSeries, $InlineSeries, $Purity,
    $Stringify, $Numify, $LoadBlessed, $QuoteNumericStrings,
    $DumperClass, $LoaderClass
);

use YAML::Node; # XXX This is a temp fix for Module::Build
use Scalar::Util qw/ openhandle /;

# XXX This VALUE nonsense needs to go.
use constant VALUE => "\x07YAML\x07VALUE\x07";

# YAML Object Properties
has dumper_class => default => sub {'YAML::Dumper'};
has loader_class => default => sub {'YAML::Loader'};
has dumper_object => default => sub {$_[0]->init_action_object("dumper")};
has loader_object => default => sub {$_[0]->init_action_object("loader")};

sub Dump {
    my $yaml = YAML->new;
    $yaml->dumper_class($YAML::DumperClass)
        if $YAML::DumperClass;
    return $yaml->dumper_object->dump(@_);
}

sub Load {
    my $yaml = YAML->new;
    $yaml->loader_class($YAML::LoaderClass)
        if $YAML::LoaderClass;
    return $yaml->loader_object->load(@_);
}

{
    no warnings 'once';
    # freeze/thaw is the API for Storable string serialization. Some
    # modules make use of serializing packages on if they use freeze/thaw.
    *freeze = \ &Dump;
    *thaw   = \ &Load;
}

sub DumpFile {
    my $OUT;
    my $filename = shift;
    if (openhandle $filename) {
        $OUT = $filename;
    }
    else {
        my $mode = '>';
        if ($filename =~ /^\s*(>{1,2})\s*(.*)$/) {
            ($mode, $filename) = ($1, $2);
        }
        open $OUT, $mode, $filename
          or YAML::Mo::Object->die('YAML_DUMP_ERR_FILE_OUTPUT', $filename, "$!");
    }
    binmode $OUT, ':utf8';  # if $Config{useperlio} eq 'define';
    local $/ = "\n"; # reset special to "sane"
    print $OUT Dump(@_);
    unless (ref $filename eq 'GLOB') {
        close $OUT
          or do {
              my $errsav = $!;
              YAML::Mo::Object->die('YAML_DUMP_ERR_FILE_OUTPUT_CLOSE', $filename, $errsav);
          }
    }
}

sub LoadFile {
    my $IN;
    my $filename = shift;
    if (openhandle $filename) {
        $IN = $filename;
    }
    else {
        open $IN, '<', $filename
          or YAML::Mo::Object->die('YAML_LOAD_ERR_FILE_INPUT', $filename, "$!");
    }
    binmode $IN, ':utf8';  # if $Config{useperlio} eq 'define';
    return Load(do { local $/; <$IN> });
}

sub init_action_object {
    my $self = shift;
    my $object_class = (shift) . '_class';
    my $module_name = $self->$object_class;
    eval "require $module_name";
    $self->die("Error in require $module_name - $@")
        if $@ and "$@" !~ /Can't locate/;
    my $object = $self->$object_class->new;
    $object->set_global_options;
    return $object;
}

my $global = {};
sub Bless {
    require YAML::Dumper::Base;
    YAML::Dumper::Base::bless($global, @_)
}
sub Blessed {
    require YAML::Dumper::Base;
    YAML::Dumper::Base::blessed($global, @_)
}
sub global_object { $global }

[+] HTML
[+] local
[-] Importer.pm [edit]
[+] IO
[+] YAML
[+] Text
[+] Package
[-] perlxstut.pod [edit]
[+] Filter
[+] CPAN
[+] Try
[+] Getopt
[-] newgetopt.pl [edit]
[-] bigint.pm [edit]
[-] experimental.pm [edit]
[-] perlfaq7.pod [edit]
[+] Module
[+] Tie
[+] LWP
[+] Parse
[-] perlglossary.pod [edit]
[-] perlxstypemap.pod [edit]
[+] JSON
[+] Locale
[+] Digest
[-] Switch.pm [edit]
[-] perldoc.pod [edit]
[-] perlfaq3.pod [edit]
[-] LWP.pm [edit]
[-] CGI.pm [edit]
[+] Crypt
[+] Config
[+] Object
[-] parent.pm [edit]
[+] WWW
[-] perlfaq9.pod [edit]
[-] perlfaq4.pod [edit]
[-] perlxs.pod [edit]
[+] Exporter
[+] List
[+] TAP
[-] Test2.pm [edit]
[-] YAML.pm [edit]
[-] perlfaq6.pod [edit]
[-] CGI.pod [edit]
[-] Digest.pm [edit]
[+] CGI
[-] Expect.pm [edit]
[+] Encode
[-] perlfaq.pm [edit]
[-] ok.pm [edit]
[+] inc
[+] autodie
[-] perlfaq1.pod [edit]
[-] bignum.pm [edit]
[+] Authen
[+] ExtUtils
[+] HTTP
[+] POD2
[+] App
[-] CPAN.pm [edit]
[+] Algorithm
[+] Data
[-] perlfaq5.pod [edit]
[+] MIME
[+] Thread
[+] Regexp
[+] Types
[+] PerlIO
[-] Env.pm [edit]
[+] MRO
[+] Test
[+] Archive
[-] bigrat.pm [edit]
[+] Net
[+] Carp
[+] Params
[-] Carp.pm [edit]
[-] perlfaq.pod [edit]
[+] Math
[-] autodie.pm [edit]
[+] Test2
[-] constant.pm [edit]
[+] Software
[+] Time
[+] IPC
[+] libwww
[+] XML
[-] perlfaq2.pod [edit]
[+] File
[-] perlfaq8.pod [edit]
[+] Term
[+] Mozilla
[+] lib
[+] Sub
[-] Fh.pm [edit]
[+] ..
[-] TimeDate.pm [edit]
[-] Fatal.pm [edit]
[+] Date
[+] Perl
[+] Pod
[-] YAML.pod [edit]